// Classic Arcade!
// Wolf Arcade Decorate
ACTOR WolfArcade_Weapon
{
	+NOCLIP
	+NOGRAVITY
	States
	{
	Spawn:
	Ready.Pistol:
		LUGR A 1
		Loop
	Fire.Pistol:
		TNT1 A 0 A_GiveInventory("WolfArcade_Weapon_Firing", 1)
		LUGR B 2
		TNT1 A 0 A_PlaySound("wolf/pistol", CHAN_WEAPON, 1.0, false, ATTN_NONE)
		LUGR C 3 BRIGHT ACS_NamedExecuteAlways("WolfArcade_FirePistol", 0)
		LUGR DE 3
		TNT1 A 0 A_TakeInventory("WolfArcade_Weapon_Firing", 1)
		Goto Ready.Pistol
	}
}

ACTOR WolfArcade_Weapon_Firing : Inventory
{
	Inventory.MaxAmount 1
}

ACTOR WolfArcade_Player
{
	+NODAMAGE
	+NOGRAVITY
	+NOBLOOD
	Monster
	Height 64
	Radius 16
	States
	{
	Spawn:
		TNT1 A 0 NoDelay A_SpawnItemEx("WolfArcade_Camera", 0, 0, 0, 0, 0, 0, 0, SXF_SETMASTER, 0, CallACS("WolfArcade_PlayerCamera"))
		Goto Idle
	Idle:
		TNT1 A -1
		Stop
	}
}

ACTOR WolfArcade_Camera
{
	+NOGRAVITY
	+NOCLIP
	States
	{
	Spawn:
		TNT1 A 1 A_Warp(AAPTR_MASTER, 0, 0, 32, 0, WARPF_NOCHECKPOSITION|WARPF_STOP|WARPF_COPYINTERPOLATION)
		Loop
	}
}

ACTOR WolfArcade_Puff : BulletPuff replaces BulletPuff
{
	+NOEXTREMEDEATH
	+BLOODLESSIMPACT
	RenderStyle None
}

ACTOR WolfArcade_Nazi : WolfensteinSS 503
{
	//$Category Wolf Arcade
	//$Sprite SSWVA1
	//$Title Nazi
	+NOBLOOD
	DropItem ""
	Scale 0.5
	Height 28
	Radius 10
	States
	{
	XDeath:
		Goto Super::Death
	}
}